NYITSUPPORT

My recent Krav Maga orange belt

2010-09-24T20:39:00.002-04:00

This is a picture taken a week after my Krav Maga orange belt test.
I train at http://www.kravmagafederation.com/

Blackberry DB Backup BESMgmt BlackberryDBBackup.exe

2010-03-12T16:20:00.002-05:00

Ok, so if anyone is interested in backing up the MSDE database for the Blackberry Enterprise Server, you may have come across a command called blackberrydbbackup.exe. And you most likely would have run into issues with using it. The help when executing the program without switches shows a command -d for specifying the database, -E for using windows credentials, and -f for the backup folder: blackberrydbbackup.exe -d BESMgmt -E -f c:\backup That does not work, no matter what you seem to do. Even though Blackberry support and all forums show it as being the proper command sequence. Well after a half hour of hitting my head against the wall, a solution was born. blackberrydbbackup -dBESMgmt -E -f c:\backup Note the no space after the -d and the .exe taken out. When the script was written, it seems someone made a few mistakes. The .exe extension is taken as a part of the switch it seems. And the help needs to be modified to reflect the -ddbname. Dont even bother using -U and -P for username and password. Nothing i tried worked. -Udomain\besadmin -Udomain\BESAdmin -U domain\besadmin -U domain\BESAdmin -Ubesadmin -UBESAdmin -U BESAdmin -U besadmin -UBESAdmin@domain -U BESAdmin@domain -U: all of the above and the same for -P ofcourse. When scheduling the script for this using Windows Scheduler, -E is enough as the windows credentials will be passed. Just enter the besadmin info when saving the job. Someone posted online about using the AT command to run as a system service along with -U and -P so as to not have to change the password for the job each time the Besadmin pw changed. That makes no difference as even if you got the -U and -P to work properly, when the besadmin pw is changed you would still have to modify the script with the new -P. By the way the tool along with blackberrydbrestore.exe is located in the tools folder on the Blackberry cd. Thank you Alex B

OLKAway Now With Vista support

2009-10-09T13:06:00.001-04:00

Long overdue update.

Added Vista support, removed old AutoIT declarations, and set the temp folder to be recreated after deletion to avoid random errors.

     #NoTrayIcon

    #Region ;**** Directives created by AutoIt3Wrapper_GUI ****

    #AutoIt3Wrapper_outfile=OLKaway.exe

    #AutoIt3Wrapper_Compression=4

    #EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

    #cs

        This script will delete the Outlook temp folder under

        c:\documents and settings\%username%\local settings\temporary internet files\OLKxxx (Windows XP/2000)

        or 

        C:\Users\%username%\AppData\Local\Microsoft\Windows\Temporary Internet Files\Content.Outlook (Windows Vista)

        It will check for the presense of the OutlookSecureTempFolder entry in the registry

        starting with Outlook 2007, all the way to Outlook 2000 working backwards.

        Once found, it will delete the contents.

        /install option will add a shortcut to the startup folder.

        /uninstall option will delete the shortcut.

        no option will just execute the removal without installing.

        created 01/07/2008

        updates 10/09/2009

            Added Vista support

            Removed old AutoIT declarations

            Corrected random Outlook issues due to the temp folder not being recreated, by creating it manually after each delete.

        ab@nyitsupport.com

    #ce

    dim $InstallPath

    $InstallPath = "C:\Program Files\NYITSupport\OLKaway\"

    Select

        case @OSVersion = "WIN_VISTA"

            #requireadmin

            Call ("StartSequence")

        case @OSVersion = "WIN_XP"

            Call ("StartSequence")

        case @OSVersion = "WIN_2000"

            $ver = RegRead("HKLM\SYSTEM\CurrentControlSet\Control\ProductOptions", "ProductType")

            If $ver = "ServerNT" then Exit

            Call ("StartSequence")

        case Else

            Exit

    EndSelect    

    Func StartSequence()

        if $CmdLine[$CmdLine[0]] = "" then 

            call ("CleanUp")

        Else

            Select

                case $CmdLine [1] = "/uninstall"

                    if not IsAdmin() then Exit

                    call ("Uninstall")

                case $CmdLine [1] = "/install" 

                    if not IsAdmin() then Exit

                    if FileExists($InstallPath) then Exit

                    Call ("Install")

                case Else

                    Exit

            EndSelect

        EndIf

    EndFunc

    func CleanUp()

        $OSTF = RegRead("HKEY_CURRENT_USER\Software\Microsoft\Office\12.0\Outlook\Security", "OutlookSecureTempFolder") ; Outlook 2007

        if @error then $OSTF = RegRead("HKEY_CURRENT_USER\Software\Microsoft\Office\11.0\Outlook\Security\", "OutlookSecureTempFolder") ; Outlook 2003

        if @error then $OSTF = RegRead("HKEY_CURRENT_USER\Software\Microsoft\Office\10.0\Outlook\Security", "OutlookSecureTempFolder") ; Outlook XP

        if @error then $OSTF = RegRead("HKEY_CURRENT_USER\Software\Microsoft\Office\9.0\Outlook\Security", "OutlookSecureTempFolder") ; Outlook 2000

        DirRemove($OSTF,1)

        DirCreate($OSTF)

    EndFunc

    Func Install()

        FileCopy (@ScriptFullPath, $InstallPath,8)

        ShellExecute("cacls.exe", '"' & StringLeft($InstallPath, StringLen($InstallPath)-1) & '" /e /c /g BUILTIN\Users:F')

        FileCreateShortcut($InstallPath &; "OLKaway.exe", @StartupCommonDir & "\NYITSUPPORT OLKaway.lnk", $InstallPath, "", "NYITSUPPORT OLKaway")

        call ("CleanUp")

    EndFunc

    Func Uninstall()

        FileDelete (@StartupCommonDir &; "\NYITSUPPORT OLKaway.lnk")

        DirRemove($InstallPath,1)

    EndFunc

WSUS Problems On Cloned Machines

2009-07-14T14:32:00.001-04:00

I ran into an interesting issue the other day. A machine registered in WSUS would appear and then dissapear from the WSUS 3 SP1 console.

Found the solution to the problem on the following links:

http://tinyurl.com/mrxrwt – best source

http://tinyurl.com/nz4mu8

http://tinyurl.com/kja3to

Here is a script that will run only once if completed successfully. It will also write a log in either case to a subfolder where it ran from with a computer name in the file name.

     #Region ;**** Directives created by AutoIt3Wrapper_GUI ****

    #AutoIt3Wrapper_outfile=WSUSFix.exe

    #EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

    #cs

        WSUSFix

            This application will repair WSUS issues that may have been caused by the machine being imaged.

            Referrenced from:

                http://www.wsuswiki.com/ClientFAQ

                http://www.experts-exchange.com/OS/Microsoft_Operating_Systems/Server/2003_Server/Q_23550840.html

                http://blog.netnerds.net/2006/12/wsus-force-registration-of-clients-that-are-not-showing-up/

        Alex Belenkiy

        ab@nyitsupport.com

        07/15/2009

    #ce

    If Not IsAdmin() then Exit ; check for admin rights

    if @OSVersion <> "WIN_XP" then Exit ; Only install on Windows XP

    if FileExists("c:\windows\WSUS\WSUSFixComplete.txt") then Exit

    dim $error, $File, $log, $logText

    $command = RunWait(@ComSpec & " /c " & "net stop wuauserv")

    if @error then 

        call("Logger", "net stop wuauserv FAILED")

        $error = 1

    Else

        call("Logger", "net stop wuauserv SUCCESSFUL")

    EndIf

    Call("RegFix", "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate", "AccountDomainSid") 

    Call("RegFix", "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate", "PingID") 

    Call("RegFix", "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate", "SusClientId") 

    Call("RegFix", "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update", "LastWaitTimeout")

    Call("RegFix", "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update", "DetectionStartTime")

    Call("RegFix", "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update", "NextDetectionTime")

    Call("RegFix", "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update", "AUState")

    $command = RunWait(@ComSpec & " /c " & "net start wuauserv")

    if @error then 

        call("Logger", "net start wuauserv FAILED")

        $error = 1

    Else

        call("Logger", "net start wuauserv SUCCESSFUL")

    EndIf

    $command = RunWait(@ComSpec & " /c " & "wuauclt /resetauthorization /detectnow")

    if @error then 

        call("Logger", "wuauclt /resetauthorization /detectnow FAILED")

        $error = 1

    Else

        call("Logger", "wuauclt /resetauthorization /detectnow SUCCESSFUL")

    EndIf

    if $error <> 1 then ; install completed successfully don't run again.

        $File = FileOpen("c:\windows\WSUS\WSUSFixComplete.txt",9)

        call ("Logger", "WSUS Fix completed successfully")

    Else ; install did not complete successfully, write a log and allow for another try

        call ("Logger", "WSUS Fix encountered errors. Will try again at next startup.")

    EndIf

    Func Logger($logText) ; write a log

        $log = FileOpen(@ScriptDir & "\Logs\" & @ComputerName & ".log", 9)

        if not @error Then

            FileWriteLine($log, @CRLF & $logText & " - " & @MON & "/" & @MDAY & "/" & @YEAR & " - " & @HOUR & ":" & @MIN)

            FileClose($log)

        EndIf

    EndFunc

    Func RegFix($RegKey, $RegVal)

        $Command = RegRead($RegKey, $RegVal)

        if not @error Then

            call("Logger", "RegRead " & $RegKey & " " & $RegVal & " " & "LOCATED")

            $Command = RegDelete($RegKey, $RegVal)

            if @error then 

                $error = 1

                call("Logger", "RegDelete " & $RegKey & " " & $RegVal & " " & "FAILED")

            Else

                call("Logger", "RegDelete " & $RegKey & " " & $RegVal & " " & "SUCCESSFUL")

            EndIf

        Else

            call("Logger", "REGREAD " & $RegKey & " " & $RegVal & " " & "NOT FOUND")

        EndIf

    EndFunc

Serial Number Retriever

2009-03-18T11:27:00.001-04:00

Yet another serial number generator. Ported from a vbscript found online.
Just feed a machine name to the script to get an output with a serial number into a csv file.
You can also feed a file with all computer names on separate lines. If executed with no options, the current computer info is returned.
If there is no input, the local machine will be used.

     #Region ;**** Directives created by AutoIt3Wrapper_GUI ****

    #AutoIt3Wrapper_outfile=SerialNumber.exe

    #EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

    #cs

        Just feed a machine name to the script to get an output with a serial number into a csv file.

        You can also feed a file with all computer names on separate lines. If executed with no options, the current computer info is returned.

        If there is no input, the local machine will be used.

        Alex Belenkiy

        09/24/08

    #ce

    #include <array.au3>

    #include <file.au3>

    dim $strComputer, $ComputersArray

    $OutputFile = FileOpen("ServiceTag " & @MON & "-" & @MDAY & "-" & @YEAR & ".csv", 10)

    FileWriteLine($OutputFile, "Machine Name, Manufacturer, Model Number, Serial Number, Part Number, SMBIOSAssetTag, OtherIdentifyingInfo")

    If $CmdLine[0] = 0 Then 

        $objWMIService = ObjGet("winmgmts:" & "{impersonationLevel=impersonate}!\\" & @ComputerName & "\root\cimv2")

        $colSMBIOS = $objWMIService.ExecQuery ("Select * from Win32_SystemEnclosure")    

        For $objSMBIOS in $colSMBIOS

            FileWriteLine($OutputFile, @ComputerName & "," & $objSMBIOS.Manufacturer & "," & $objSMBIOS.Model & "," & $objSMBIOS.SerialNumber & "," & $objSMBIOS.PartNumber & $objSMBIOS.SMBIOSAssetTag & $objSMBIOS.OtherIdentifyingInfo)

        Next

    Else

        if not FileExists($CmdLine[1]) Then

            $objWMIService = ObjGet("winmgmts:" & "{impersonationLevel=impersonate}!\\" & $CmdLine[1] & "\root\cimv2")

            if not @error Then

                $colSMBIOS = $objWMIService.ExecQuery ("Select * from Win32_SystemEnclosure")    

                For $objSMBIOS in $colSMBIOS

                    FileWriteLine($OutputFile, $CmdLine[1] & "," & $objSMBIOS.Manufacturer & "," & $objSMBIOS.Model & "," & $objSMBIOS.SerialNumber & "," & $objSMBIOS.PartNumber & $objSMBIOS.SMBIOSAssetTag & $objSMBIOS.OtherIdentifyingInfo)

                Next

            EndIf

        Else

            _FileReadToArray($CmdLine[1],$ComputersArray)

            For $a = 1 to $ComputersArray[0]

                $objWMIService = ObjGet("winmgmts:" & "{impersonationLevel=impersonate}!\\" & $ComputersArray[$a] & "\root\cimv2")

                if not @error Then

                    $colSMBIOS = $objWMIService.ExecQuery ("Select * from Win32_SystemEnclosure")    

                    For $objSMBIOS in $colSMBIOS

                        FileWriteLine($OutputFile, $ComputersArray[$a] & "," & $objSMBIOS.Manufacturer & "," & $objSMBIOS.Model & "," & $objSMBIOS.SerialNumber & "," & $objSMBIOS.PartNumber & $objSMBIOS.SMBIOSAssetTag & $objSMBIOS.OtherIdentifyingInfo)

                    Next

                EndIf

            Next

        EndIf

    EndIf

    FileClose($OutputFile)

Folder Duplicator

2009-03-18T11:21:00.001-04:00

This script lets you choose a folder and copy it to every subfolder in the chosen destination.

Created it with a specific purpose of updating 200+ Citrix server user folders.

A catalog configuration file for Document Locator had to be placed under c:\documents and settings\username\application data\ColumbiaSoft

I created a folder called Application Data, then ColumbiaSoft under it, and placed the catalog there. Ran the script, selected the new Application Data folder, and chose c:\documents and settings as the destination. The script merged the existing application data with the new one under each username folder. Please pay attention as the script will overwrite existing files without prompting.

     #Region ;**** Directives created by AutoIt3Wrapper_GUI ****

    #AutoIt3Wrapper_outfile=FolderDuplicator.exe

    #EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

    #cs

        FolderDuplicator

        03/11/2009

        Alex Belenkiy - ab@nyitsupport.com

        This script will duplicate the source directory into every subfolder of the destination, 

        overwriting existing files in it's path.

        Use with caution!!!

    #ce

    #Include <File.au3>

    $Warning = MsgBox(1, "Folder Duplicator", "This application will duplicate the selected" & @CRLF & "source folder into all destination subfolders" & @CRLF & "All existing files will be overwritten")

    if $Warning = 2 then Exit

    $source = FileSelectFolder("Select Folder to Copy", "")

    if @error Then 

        MsgBox(0, "Folder Duplicator", "Invalid Source Folder")

        Exit

    EndIf

    $destination = FileSelectFolder("Select Destination Folder", "")

    if @error then 

        MsgBox (0, "Folder Duplicator", "Invalid Destination Folder")

        Exit

    EndIf

    $sourceSplit = StringSplit($source, "\")

    If StringRight($destination, 1) <> "\" Then $destination &= "\"

    $FileList = _FileListToArray ($destination, "*.*", 2)

    if @error then Exit

    for $a = 1 to $FileList [0]

        DirCopy ($source, $destination & $FileList[$a] & "\" & $sourceSplit[$sourceSplit[0]], 1)

        if @error then

            MsgBox(0, "Folder Duplicator", "Error encountered while copying folders")

            Exit

        EndIf

    Next

    MsgBox(0,"Folder Duplicator", "Done!!!")

Shutdown 2.0

2009-03-18T11:15:00.001-04:00

As it turned out, my first shutdown script did not work unless the user is logged onto the machine.

This new one works without anyone being logged on. It relies on the service.au3 file. It was downloaded from an AutoIt forum http://www.autoitscript.com/forum/index.php?showtopic=80201

Service.au3:

     #AutoIt3Wrapper_Change2CUI=y

    #include-once

    #include<WinApi.au3>

    #region Defined Variables and Constants

    Global $STANDARD_RIGHTS_REQUIRED = 0x000F0000

    ; Service Control Manager access types

    Global Const $SC_MANAGER_CONNECT = 0x0001

    Global Const $SC_MANAGER_CREATE_SERVICE = 0x0002

    Global Const $SC_MANAGER_ENUMERATE_SERVICE = 0x0004

    Global Const $SC_MANAGER_LOCK = 0x0008

    Global Const $SC_MANAGER_QUERY_LOCK_STATUS = 0x0010

    Global Const $SC_MANAGER_MODIFY_BOOT_CONFIG = 0x0020

    Global Const $SC_MANAGER_ALL_ACCESS = BitOR($STANDARD_RIGHTS_REQUIRED, $SC_MANAGER_CONNECT, $SC_MANAGER_CREATE_SERVICE, $SC_MANAGER_ENUMERATE_SERVICE, $SC_MANAGER_LOCK, $SC_MANAGER_QUERY_LOCK_STATUS, $SC_MANAGER_MODIFY_BOOT_CONFIG)

    ; Service Access Types

    Global Const  $SERVICE_QUERY_CONFIG = 0x0001

    Global Const $SERVICE_CHANGE_CONFIG = 0x0002

    Global Const $SERVICE_QUERY_STATUS = 0x0004

    Global Const $SERVICE_ENUMERATE_DEPENDENTS = 0x0008

    Global Const $SERVICE_START = 0x0010

    Global Const $SERVICE_STOP = 0x0020

    Global Const $SERVICE_PAUSE_CONTINUE = 0x0040

    Global Const $SERVICE_INTERROGATE = 0x0080

    Global Const $SERVICE_USER_DEFINED_CONTROL = 0x0100

    Global $SERVICE_ALL_ACCESS = BitOR($STANDARD_RIGHTS_REQUIRED, $SERVICE_QUERY_CONFIG, $SERVICE_CHANGE_CONFIG, $SERVICE_QUERY_STATUS, $SERVICE_ENUMERATE_DEPENDENTS, $SERVICE_START, $SERVICE_STOP, $SERVICE_PAUSE_CONTINUE, $SERVICE_INTERROGATE, $SERVICE_USER_DEFINED_CONTROL)

    ; Service Controls

    Global Const $SERVICE_CONTROL_STOP = 0x00000001

    Global Const $SERVICE_CONTROL_PAUSE = 0x00000002

    Global Const $SERVICE_CONTROL_CONTINUE = 0x00000003

    Global Const $SERVICE_CONTROL_INTERROGATE = 0x00000004

    Global Const $SERVICE_CONTROL_SHUTDOWN = 0x00000005

    Global Const $SERVICE_CONTROL_PARAMCHANGE = 0x00000006

    Global Const $SERVICE_CONTROL_NETBINDADD = 0x00000007

    Global Const $SERVICE_CONTROL_NETBINDREMOVE = 0x00000008

    Global Const $SERVICE_CONTROL_NETBINDENABLE = 0x00000009

    Global Const $SERVICE_CONTROL_NETBINDDISABLE = 0x0000000A

    Global Const $SERVICE_CONTROL_DEVICEEVENT = 0x0000000B

    Global Const $SERVICE_CONTROL_HARDWAREPROFILECHANGE = 0x0000000C

    Global Const $SERVICE_CONTROL_POWEREVENT = 0x0000000D

    Global Const $SERVICE_CONTROL_SESSIONCHANGE = 0x0000000E

    ; Service Types

    Global Const $SERVICE_KERNEL_DRIVER = 0x00000001

    Global Const $SERVICE_FILE_SYSTEM_DRIVER = 0x00000002

    Global Const $SERVICE_ADAPTER = 0x00000004

    Global Const $SERVICE_RECOGNIZER_DRIVER = 0x00000008

    Global Const $SERVICE_DRIVER = BitOR($SERVICE_KERNEL_DRIVER, $SERVICE_FILE_SYSTEM_DRIVER, $SERVICE_RECOGNIZER_DRIVER)

    Global Const $SERVICE_WIN32_OWN_PROCESS = 0x00000010

    Global Const $SERVICE_WIN32_SHARE_PROCESS = 0x00000020

    Global Const $SERVICE_WIN32 = BitOR($SERVICE_WIN32_OWN_PROCESS, $SERVICE_WIN32_SHARE_PROCESS)

    Global Const $SERVICE_INTERACTIVE_PROCESS = 0x00000100

    Global Const $SERVICE_TYPE_ALL = BitOR($SERVICE_WIN32, $SERVICE_ADAPTER, $SERVICE_DRIVER, $SERVICE_INTERACTIVE_PROCESS)

    ; Service Start Types

    Global Const $SERVICE_BOOT_START = 0x00000000

    Global Const $SERVICE_SYSTEM_START = 0x00000001

    Global Const $SERVICE_AUTO_START = 0x00000002

    Global Const $SERVICE_DEMAND_START = 0x00000003

    Global Const $SERVICE_DISABLED = 0x00000004

    ; Service Error Control

    Global Const $SERVICE_ERROR_IGNORE = 0x00000000

    Global Const $SERVICE_ERROR_NORMAL = 0x00000001

    Global Const $SERVICE_ERROR_SEVERE = 0x00000002

    Global Const $SERVICE_ERROR_CRITICAL = 0x00000003

    Global Const $SERVICE_ACCEPT_HARDWAREPROFILECHANGE = 0x20

    Global Const $SERVICE_ACCEPT_NETBINDCHANGE = 0x10

    Global Const $SERVICE_ACCEPT_PARAMCHANGE = 0x8

    Global Const $SERVICE_ACCEPT_PAUSE_CONTINUE = 0x2

    Global Const $SERVICE_ACCEPT_POWEREVENT = 0x40

    Global Const $SERVICE_ACCEPT_SESSIONCHANGE = 0x80

    Global Const $SERVICE_ACCEPT_PRESHUTDOWN = 0x100

    Global Const $SERVICE_ACCEPT_SHUTDOWN = 0x4

    Global Const $SERVICE_ACCEPT_STOP = 0x1

    Global Const $SERVICE_ACTIVE = 0x1

    Global Const $SERVICE_INACTIVE = 0x2

    Global Const $SERVICE_PAUSE_PENDING = 0x6

    Global Const $SERVICE_PAUSED = 0x7

    Global Const $SERVICE_RUNNING = 0x4

    Global Const $SERVICE_START_PENDING = 0x2

    Global Const $SERVICE_STOP_PENDING = 0x3

    Global Const $SERVICE_STOPPED = 0x1

    Global Const $SERVICE_CONTINUE_PENDING = 0x5

    ;

    Global $tServiceName,$tServiceCtrl,$tServiceMain,$service_debug_mode = False

    Global $tService_Status = DllStructCreate("dword dwServiceType;dword dwCurrentState;dword dwControlsAccepted;dword dwWin32ExitCode;dword dwServiceSpecificExitCode;dword dwCheckPoint;dword dwWaitHint")

    Global $tService_Status_handle

    Global Const $NO_ERROR = 0

    Global Const $NTSL_LOOP_WAIT = -1

    Global $service_stop_event

    Global $NTSL_ERROR_SERVICE_STATUS = 2

    Global Const $WAIT_OBJECT_0 = 0x0

    #endregion

    #region Functions

    Func _CreateService($sComputerName, $sServiceName, $sDisplayName, $sBinaryPath, $sServiceUser = "LocalSystem", $sPassword = "", $nServiceType = 0x00000010, $nStartType = 0x00000002, $nErrorType = 0x00000001, $nDesiredAccess = 0x000f01ff, $sLoadOrderGroup = "")

        Local $hAdvapi32

        Local $hKernel32

        Local $arRet

        Local $hSC

        Local $lError = -1   

        $hAdvapi32 = DllOpen("advapi32.dll")

        If $hAdvapi32 = -1 Then Return 0

        $hKernel32 = DllOpen("kernel32.dll")

        If $hKernel32 = -1 Then Return 0

        $arRet = DllCall($hAdvapi32, "long", "OpenSCManager", "str", $sComputerName, "str", "ServicesActive", "long", $SC_MANAGER_ALL_ACCESS)

        If $arRet[0] = 0 Then

            $arRet = DllCall($hKernel32, "long", "GetLastError")

            $lError = $arRet[0]

        Else

            $hSC = $arRet[0]

            $arRet = DllCall($hAdvapi32, "long", "OpenService", "long", $hSC, "str", $sServiceName, "long", $SERVICE_INTERROGATE)

            If $arRet[0] = 0 Then

                $arRet = DllCall($hAdvapi32, "long", "CreateService", "long", $hSC, "str", $sServiceName, "str", $sDisplayName, "long", $nDesiredAccess, "long", $nServiceType, "long", $nStartType, "long", $nErrorType, "str", $sBinaryPath, "str", $sLoadOrderGroup, "ptr", 0, "str", "", "str", $sServiceUser, "str", $sPassword)

                If $arRet[0] = 0 Then            

                    $arRet = DllCall($hKernel32, "long", "GetLastError")

                    $lError = $arRet[0]

                Else

                    DllCall($hAdvapi32, "int", "CloseServiceHandle", "long", $arRet[0])

                EndIf

            Else

                DllCall($hAdvapi32, "int", "CloseServiceHandle", "long", $arRet[0])

            EndIf      

            DllCall($hAdvapi32, "int", "CloseServiceHandle", "long", $hSC)

        EndIf

        DllClose($hAdvapi32)

        DllClose($hKernel32)   

        If $lError <> -1 Then 

            SetError($lError)

            Return 0

        EndIf

        Return 1

    EndFunc

    Func _DeleteService($sComputerName, $sServiceName)

        Local $hAdvapi32

        Local $hKernel32

        Local $arRet

        Local $hSC

        Local $hService

        Local $lError = -1   

        $hAdvapi32 = DllOpen("advapi32.dll")

        If $hAdvapi32 = -1 Then Return 0

        $hKernel32 = DllOpen("kernel32.dll")

        If $hKernel32 = -1 Then Return 0

        $arRet = DllCall($hAdvapi32, "long", "OpenSCManager", "str", $sComputerName, "str", "ServicesActive", "long", $SC_MANAGER_ALL_ACCESS)

        If $arRet[0] = 0 Then

            $arRet = DllCall($hKernel32, "long", "GetLastError")

            $lError = $arRet[0]

        Else

            $hSC = $arRet[0]

            $arRet = DllCall($hAdvapi32, "long", "OpenService", "long", $hSC, "str", $sServiceName, "long", $SERVICE_ALL_ACCESS)

            If $arRet[0] = 0 Then

                $arRet = DllCall($hKernel32, "long", "GetLastError")

                $lError = $arRet[0]

            Else

                $hService = $arRet[0]

                $arRet = DllCall($hAdvapi32, "int", "DeleteService", "long", $hService)

                If $arRet[0] = 0 Then

                    $arRet = DllCall($hKernel32, "long", "GetLastError")

                    $lError = $arRet[0]

                EndIf

                DllCall($hAdvapi32, "int", "CloseServiceHandle", "long", $hService)

            EndIf

            DllCall($hAdvapi32, "int", "CloseServiceHandle", "long", $hSC)

        EndIf

        DllClose($hAdvapi32)

        DllClose($hKernel32)   

        If $lError <> -1 Then 

            SetError($lError)

            Return 0

        EndIf

        Return 1

    EndFunc

    Func _StopService($sComputerName, $sServiceName)

        Local $hAdvapi32

        Local $hKernel32

        Local $arRet

        Local $hSC

        Local $hService

        Local $lError = -1

        $hAdvapi32 = DllOpen("advapi32.dll")

        If $hAdvapi32 = -1 Then Return 0

        $hKernel32 = DllOpen("kernel32.dll")

        If $hKernel32 = -1 Then Return 0

        $arRet = DllCall($hAdvapi32, "long", "OpenSCManager", "str", $sComputerName, "str", "ServicesActive", "long", $SC_MANAGER_CONNECT)

        If $arRet[0] = 0 Then

            $arRet = DllCall($hKernel32, "long", "GetLastError")

            $lError = $arRet[0]

        Else

            $hSC = $arRet[0]

            $arRet = DllCall($hAdvapi32, "long", "OpenService", "long", $hSC, "str", $sServiceName, "long", $SERVICE_STOP)

            If $arRet[0] = 0 Then

                $arRet = DllCall($hKernel32, "long", "GetLastError")

                $lError = $arRet[0]

            Else

                $hService = $arRet[0]

                $arRet = DllCall($hAdvapi32, "int", "ControlService", "long", $hService, "long", $SERVICE_CONTROL_STOP, "str", "")

                If $arRet[0] = 0 Then

                    $arRet = DllCall($hKernel32, "long", "GetLastError")

                    $lError = $arRet[0]

                EndIf

                DllCall($hAdvapi32, "int", "CloseServiceHandle", "long", $hService)         

            EndIf

            DllCall($hAdvapi32, "int", "CloseServiceHandle", "long", $hSC)

        EndIf

        DllClose($hAdvapi32)

        DllClose($hKernel32)   

        If $lError <> -1 Then 

            SetError($lError)

            Return 0

        EndIf

        Return 1

    EndFunc

    Func _ServiceExists($sComputerName, $sServiceName)

        Local $hAdvapi32

        Local $hKernel32

        Local $arRet

        Local $hSC

        Local $hService

        Local $lError = -1

        $hAdvapi32 = DllOpen("advapi32.dll")

        If $hAdvapi32 = -1 Then Return 0

        $hKernel32 = DllOpen("kernel32.dll")

        If $hKernel32 = -1 Then Return 0

        $arRet = DllCall($hAdvapi32, "long", "OpenSCManager", "str", $sComputerName, "str", "ServicesActive", "long", $SC_MANAGER_CONNECT)

        If $arRet[0] = 0 Then

            $arRet = DllCall($hKernel32, "long", "GetLastError")

            $lError = $arRet[0]

        Else

            $hSC = $arRet[0]

            $arRet = DllCall($hAdvapi32, "long", "OpenService", "long", $hSC, "str", $sServiceName, "long", $SERVICE_STOP)

            If $arRet[0] = 0 Then

                $arRet = DllCall($hKernel32, "long", "GetLastError")

                $lError = $arRet[0]    

            EndIf

            DllCall($hAdvapi32, "int", "CloseServiceHandle", "long", $hSC)

        EndIf

        DllClose($hAdvapi32)

        DllClose($hKernel32)   

        If $lError <> -1 Then 

            SetError($lError)

            Return 0

        EndIf

        Return 1

    EndFunc

    Func _Service_Cleanup()

        $service_error = _WinAPI_GetLastError()

        If ($tService_Status_handle) Then _Service_ReportStatus($SERVICE_STOPPED, $service_error, 0);

    EndFunc

    Func _Service_Ctrl($ctrlCode)

        Switch ($ctrlCode)

            Case $SERVICE_CONTROL_PAUSE

                DllStructSetData($tService_Status, "dwCurrentState", $SERVICE_PAUSED)

            Case $SERVICE_CONTROL_CONTINUE

                DllStructSetData($tService_Status, "dwCurrentState", $SERVICE_RUNNING)

            Case $SERVICE_CONTROL_STOP

                _Service_ReportStatus($SERVICE_STOP_PENDING, $NO_ERROR, 0);

                _Service_SetStopEvent();

                _Service_Cleanup()

                Exit

            Case $SERVICE_CONTROL_INTERROGATE

                ;break;

                ; invalid control code

                ;

            Case Else

                ;

        EndSwitch

        _Service_ReportStatus(DllStructGetData($tService_Status, "dwCurrentState"), $NO_ERROR, 0);

    EndFunc

    Func _Service_Halting()

        Return (_WinAPI_WaitForSingleObject($service_stop_event, $NTSL_LOOP_WAIT) == $WAIT_OBJECT_0);

    EndFunc

    Func _Service_Init($sServiceName)    

        $tServiceCtrl = DllCallbackRegister("_Service_Ctrl", "int", "uint")

        $tServiceMain = DllCallbackRegister("_Service_ServiceMain", "int", "int;str")    

        $tdispatchTable = DllStructCreate("ptr[2];ptr[2]")

        $tServiceName = DllStructCreate("char[128]")

        DllStructSetData($tServiceName, 1, $sServiceName)

        DllStructSetData($tdispatchTable, 1, DllStructGetPtr($tServiceName), 1)

        DllStructSetData($tdispatchTable, 1, DllCallbackGetPtr($tServiceMain), 2)

        DllStructSetData($tdispatchTable, 2, 0, 1)

        DllStructSetData($tdispatchTable, 2, 0, 2)

        $ret = DllCall("advapi32.dll", "int", "StartServiceCtrlDispatcher", "ptr", DllStructGetPtr($tdispatchTable))

        ;If $ret[0] = 0 Then MsgBox(0, "", " Error " & _WinAPI_GetLastError() & @CRLF)

    EndFunc 

    Func _Service_ReportStatus($currentState, $exitCode, $waitHint)

        Local $checkPoint = 1;

        Local $rc = True;

        If Not ($service_debug_mode) Then ;when debugging we don't report to the SCM

            If ($currentState == $SERVICE_START_PENDING) Then

                DllStructSetData($tService_Status, "dwControlsAccepted", 0);

            Else

                DllStructSetData($tService_Status, "dwControlsAccepted", $SERVICE_ACCEPT_STOP)

            EndIf

            DllStructSetData($tService_Status, "dwCurrentState", $currentState)

            DllStructSetData($tService_Status, "dwWin32ExitCode", $exitCode)

            DllStructSetData($tService_Status, "dwWaitHint", $waitHint)

            If $currentState == $SERVICE_RUNNING Or $currentState == $SERVICE_STOPPED Then

                DllStructSetData($tService_Status, "dwCheckPoint", 0)

            Else

                DllStructSetData($tService_Status, "dwCheckPoint", $checkPoint + 1);

            EndIf

            ; report the status of the service to the service control manager.

            If Not ($rc = _Service_SetServiceStatus($tService_Status_handle, DllStructGetPtr($tService_Status))) Then ConsoleWrite("+ " & $NTSL_ERROR_SERVICE_STATUS & @TAB & _WinAPI_GetLastError() & @CRLF)

        EndIf

        Return ($rc);

    EndFunc

    Func _Service_ServiceMain($iArg, $sArgs)

        $ret = DllCall("advapi32.dll", "hwnd", "RegisterServiceCtrlHandler", "ptr", DllStructGetPtr($tServiceName), "ptr", DllCallbackGetPtr($tServiceCtrl));register service

        If $ret[0] = 0 Then

            MsgBox(0, "Error", _WinAPI_GetLastError())

            Exit

        EndIf

        $tService_Status_handle = $ret[0]

        If Not ($tService_Status_handle) Then

            _Service_Cleanup()

            Return

        EndIf

        DllStructSetData($tService_Status, "dwServiceType", $SERVICE_WIN32_OWN_PROCESS)

        DllStructSetData($tService_Status, "dwServiceSpecificExitCode", 0);

        ; report the status to the service control manager.

        If Not (_Service_ReportStatus($SERVICE_START_PENDING, $NO_ERROR, 3000)) Then

            _Service_Cleanup()

            Return

        EndIf

        _Service_Start($iArg, $sArgs);

        _Main()

        Return;

    EndFunc

    Func _Service_SetServiceStatus($hServiceStatus, $lpServiceStatus)

        $ret = DllCall("advapi32.dll", "int", "SetServiceStatus", "hwnd", $hServiceStatus, "ptr", $lpServiceStatus)

        Return $ret[0]

    EndFunc

    Func _Service_SetStopEvent()

        If ($service_stop_event) Then _WinAPI_SetEvent($service_stop_event) 

    EndFunc 

    Func _Service_Start($argc, $argv)

        If Not (_Service_ReportStatus($SERVICE_START_PENDING, $NO_ERROR, 3000)) Then Return

        $service_stop_event = _WinAPI_CreateEvent(0, True, False, 0);

        If Not ($service_stop_event) Then Return;

        ;report the status to the service control manager.

        If Not _Service_ReportStatus($SERVICE_START_PENDING, $NO_ERROR, 3000) Then Return;

        ;report the status to the service control manager.

        If Not _Service_ReportStatus($SERVICE_RUNNING, $NO_ERROR, 0) Then Return;

    EndFunc

    #endregion

Shutdown.au3

    #NoTrayIcon

    #cs

        NYITSUPPORTShutdown 2.0

        This script will shut down a machine on a schedule.

        The program should be launched as a domain computer startup policy as follows

        \\SERVER\SHARE\NYITSUPPORTShutDown.exe /install

        A policy should be put in that adds a registry key "HKEY_LOCAL_MACHINE\SOFTWARE\NYITSUPPORT\Shutdown", "Shutdown"=2300

        The time is specified in a 4 digit military time format (2330 = 11:30 PM)

        /uninstall will remove the application and registry key

        Service.au3 was downloaded from http://www.autoitscript.com/forum/index.php?showtopic=80201

    ; Alex Belenkiy ab@nyitsupport.com

    ; 02/02/2009

    #ce

    AutoItSetOption ("TrayIconHide",1)

    #include <Date.au3>

    #include <array.au3>

    #include <service.au3>

    if not IsAdmin() then Exit

    Dim $InstallPath

    Global $sServiceName = "NYITSUPPORTShutdown"

    if $CmdLine[0] = "" then Exit

    $InstallPath = "C:\Program Files\NYITSUPPORT\ShutDown\"

    Select

        case $CmdLine [1] = "/uninstall"

            if not FileExists($InstallPath) then Exit

            call ("Uninstall")

        case $CmdLine [1] = "/install" 

            if $CmdLine[0] <> 2 then Exit

            if $CmdLine [2] = "" then Exit

            if not StringIsDigit ($CmdLine[2]) then Exit

            if stringlen($CmdLine[2]) <> 4 then Exit

            if StringLeft($CmdLine[2], 2) > 23 then Exit

            if StringRight($CmdLine[2], 2) >59 then Exit

            Call ("Install")

        case $CmdLine [1] = "/NYITSUPPORTShutdown"

            _Service_init($sServiceName)

    EndSelect

    Func Install()

        $ShutdownSplit = StringSplit(RegRead("HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\NYITSUPPORTShutdown", "ImagePath"), " ")

        $Shutdown = $ShutdownSplit[$ShutdownSplit[0]]

        if not @error Then

            if $Shutdown = $CmdLine[2] then Exit

            RunWait (@SystemDir & '\net stop "NYITSUPPORT Shutdown"', "")

            FileCopy (@ScriptFullPath, $InstallPath,9)

            $NewShutdown = $ShutdownSplit[1] & " " 

             for $a = 2 to ($ShutdownSplit[0] - 1)

                $NewShutdown = $NewShutdown & $ShutdownSplit[$a] & " "

            Next

            $NewShutdown = $NewShutdown & $CmdLine[2]

            RegWrite("HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\NYITSUPPORTShutdown", "ImagePath", "REG_EXPAND_SZ", $NewShutdown)

            RunWait (@SystemDir & '\net start "NYITSUPPORT Shutdown"', "")

            Exit

        Else

            FileCopy (@ScriptFullPath, $InstallPath,9)

            $log = FileOpen("\\server\NYITSUPPORT\ShutDown\Logs\" & @ComputerName & ".log",9)

            _CreateService("",$sServiceName, "NYITSUPPORT Shutdown", $InstallPath & "NYITSUPPORTShutdown.exe /NYITSUPPORTShutdown " & $CmdLine[2])

            If @error Then

                FileWriteLine($log, @CRLF & "_CreateService failed - " & @MON & "/" & @MDAY & "/" & @YEAR & " - " & @HOUR & ":" & @MIN)

            EndIf

            FileWriteLine($log, @CRLF & "Installed - " & @MON & "/" & @MDAY & "/" & @YEAR & " - " & @HOUR & ":" & @MIN)

            RunWait (@SystemDir & '\net start "NYITSUPPORT Shutdown"', "")

            FileClose($log)

            Exit        

        EndIf    

    EndFunc   ;==>InstallService

    Func Uninstall()

        $log = FileOpen("\\server\NYITSUPPORT\ShutDown\Logs\" & @ComputerName & ".log",9)

        _StopService(".", $sServiceName)

        if @error then 

            FileWriteLine($log, @CRLF & "_StopService failed - " & @MON & "/" & @MDAY & "/" & @YEAR & " - " & @HOUR & ":" & @MIN)

        EndIf

        _DeleteService(".", $sServiceName)

        if @error then 

            FileWriteLine($log, @CRLF & "_DeleteService failed - " & @MON & "/" & @MDAY & "/" & @YEAR & " - " & @HOUR & ":" & @MIN)

        EndIf

        DirRemove($InstallPath,1)

        FileWriteLine($log, @CRLF & "Uninstalled - " & @MON & "/" & @MDAY & "/" & @YEAR & " - " & @HOUR & ":" & @MIN)

        FileClose($log)

        Exit

    EndFunc

    Func _main()

        if $CmdLine[0] <> 2 then Exit

        if $CmdLine [2] = "" then Exit

        if not StringIsDigit ($CmdLine[2]) then Exit

        if stringlen($CmdLine[2]) <> 4 then Exit

        if StringLeft($CmdLine[2], 2) > 23 then Exit

        if StringRight($CmdLine[2], 2) >59 then Exit

        $H = StringLeft($CmdLine[2],2)

        $M = StringRight($CmdLine[2],2)

        While 1

            if @MIN = $M And @HOUR = $H then 

                Run (@SystemDir & '\shutdown.exe /s /f /t 300 /c "Scheduled shutdown in progress. ' & @CRLF & 'Please close all open applications and save your data.' & @crlf & 'The system will shut down in 5 minutes."', "")

                Exit

            EndIf

            sleep (60000)

        WEnd

    EndFunc

Enjoy!!!

Canon PowerShot SD750 Button Board Repair / Replacement

2009-02-18T20:37:00.001-05:00

I posted an instructable, check it out. http://www.instructables.com/id/Canon_PowerShot_SD750_Button_Board_Replacement/

The Incredible Alex :)

2009-01-07T23:16:00.002-05:00

Symantec Antivirus Removal And Other Tips

2008-11-17T10:35:00.001-05:00

Symantec AntiVirus (SAV) Removal:

My Favorive Manual Way: http://tinyurl.com/2dgmow

Automatic Way: SCSCleanWipe3.1.zip

http://tinyurl.com/5vfhx9

Request it from Symantec or contact me and i will email it to you.

Remove a few items CleanWipe leaves: http://tinyurl.com/599mwx

Norton AntiVirus (NAV) automatically: http://tinyurl.com/7eqv8

Uninstall without a password for removal:

http://tinyurl.com/5chfaz

Misc Symantec problems:

http://tinyurl.com/5zn8e9

Copy and Paste My Scripts

2008-10-06T20:39:00.001-04:00

If anyone has any issues copying my scripts, as in everything pasting on one line, just do the following:

Paste into wordpad or word, not notepad or autoitscript.

Then save the file as an .au3.

You should then be able to open it in notepad or the Scite editor properly.

Outlook CSV Import

2008-10-06T20:34:00.001-04:00

OutlookCSVImport - Import a CSV file into Outlook.
Match up the necessary fields and modify the script if needed. Remove or add any additional fields.

Based on http://tinyurl.com/4uce9k
Download Microsoft Outlook VBA Language Reference for other properties that were not listed here.

There were 4 properties in an export i originally created this for that do not have a corresponding field in Outlook. I added them as part of the Body field (notes field).

The script will add the excel file into the default Outlook Contacts folder. Something to keep in mind while testing :)

Sort the Excel file by the FileAs field. My export came from http://www.codetwo.com/ Outlook export tool.
The client this was made for had custom fields that Outlook would not export out. The third party tool did a great job.
Renamed a few of the custom contact fields to what was needed and set the rest to be part of notes.
Outlook's natural import/export function with the "Map Custom Fields" does not work correctly. Quite a few existing Outlook fields,
do not export or import, even while it creates a csv column entry for the field (nickname is one example).
Called Microsoft on this issue. Will see what answer they come up with.

If the program crashes at any point look for the contact that crashed it, i had a field with a #name? in it that caused a crash.

     #Region ;**** Directives created by AutoIt3Wrapper_GUI ****

    #AutoIt3Wrapper_outfile=OutlookCSVImport.exe

    #EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

    #cs

        OutlookCSVImport - Import a CSV file into Outlook.

        Match up the necessary fields and modify the script if needed. Remove or add any additional fields.

        Based on http://tinyurl.com/4uce9k

        Download Microsoft Outlook VBA Language Reference for other properties that were not listed here.

        There were 4 properties in an export i originally created this for that do not have a corresponding field in Outlook.

        I added them as part of the Body field (notes field).

        The script will add the excel file into the default Outlook Contacts folder. Something to keep in mind while testing :)

        Sort the Excel file by the FileAs field. My export came from http://www.codetwo.com/ Outlook export tool.

        The client this was made for had custom fields that Outlook would not export out. The third party tool did a great job.

        Renamed a few of the custom contact fields to what was needed and set the rest to be part of notes.

        Outlook's natural import/export function with the "Map Custom Fields" does not work correctly. Quite a few existing Outlook fields,

        do not export or import, even while it creates a csv column entry for the field (nickname is one example).

        Called Microsoft on this issue. Will see what answer they come up with.

        Visit http://nyitsupport.blogspot.com for an update.

        If the program crashes at any point look for the contact that crashed it, i had a field with a #name? in it that caused a crash.

        Alex Belenkiy 

        ab@nyitsupport.com

        10/06/08

    #ce

    Const $olContactItem = 2

    $objOutlook = ObjCreate("Outlook.Application")

    $objExcel = ObjCreate("Excel.Application")

    $ExcelFile = FileOpenDialog("Please choose an Excel file to open", @WorkingDir, "Excel Files (*.xls;*.xlsx;*.csv)",1)

    $objWorkbook = $objExcel.Workbooks.Open($ExcelFile)

    $x = 2

    Do 

        $objContact = $objOutlook.CreateItem($olContactItem)

        ;---------------------------------------------------------------------------------------------

        $objContact.AssistantName = $objExcel.Cells($x,2).Value

        $objContact.AssistantTelephoneNumber =     $objExcel.Cells($x,3).Value

        $objContact.Body = "Assistant's Email: " & $objExcel.Cells($x,1).Value & @CRLF & "Contact Type: " & $objExcel.Cells($x,13).Value & @CRLF & "Contacts: " & $objExcel.Cells($x,14).Value & @CRLF & "Cross Street: " & $objExcel.Cells($x,15).Value & @CRLF & "Private Number: " & $objExcel.Cells($x,49).Value & @CRLF & @CRLF & @CRLF & $objExcel.Cells($x,4).Value

        $objContact.BusinessAddress = $objExcel.Cells($x,5).Value

        $objContact.BusinessAddressCity = $objExcel.Cells($x,6).Value

        $objContact.BusinessAddressPostalCode = $objExcel.Cells($x,7).Value

        $objContact.BusinessAddressState = $objExcel.Cells($x,8).Value

        $objContact.BusinessAddressStreet = $objExcel.Cells($x,9).Value

        $objContact.Categories = $objExcel.Cells($x,10).Value

        $objContact.CompanyName = $objExcel.Cells($x,11).Value

        $objContact.PrimaryTelephoneNumber = $objExcel.Cells($x,12).Value

        $objContact.Email1Address = $objExcel.Cells($x,16).Value

        $objContact.Email1DisplayName = $objExcel.Cells($x,17).Value

        $objContact.Email2Address = $objExcel.Cells($x,18).Value

        $objContact.Email2DisplayName = $objExcel.Cells($x,19).Value

        $objContact.Email3Address = $objExcel.Cells($x,20).Value

        $objContact.Email3DisplayName = $objExcel.Cells($x,21).Value

        $objContact.BusinessFaxNumber = $objExcel.Cells($x,22).Value

        $objContact.HomeFaxNumber = $objExcel.Cells($x,23).Value

        $objContact.OtherFaxNumber = $objExcel.Cells($x,24).Value

        $objContact.FileAs = $objExcel.Cells($x,25).Value

        $objContact.FirstName = $objExcel.Cells($x,26).Value

        $objContact.FullName =     $objExcel.Cells($x,27).Value

        $objContact.HomeAddress = $objExcel.Cells($x,28).Value

        $objContact.HomeAddressCity = $objExcel.Cells($x,29).Value

        $objContact.HomeAddressPostalCode = $objExcel.Cells($x,30).Value

        $objContact.HomeAddressState = $objExcel.Cells($x,31).Value

        $objContact.HomeAddressStreet = $objExcel.Cells($x,32).Value

        $objContact.JobTitle = $objExcel.Cells($x,33).Value

        $objContact.LastName = $objExcel.Cells($x,34).Value

        $objContact.MiddleName = $objExcel.Cells($x,35).Value

        $objContact.Nickname = $objExcel.Cells($x,36).Value

        $objContact.OtherAddress = $objExcel.Cells($x,37).Value

        $objContact.OtherAddressCity = $objExcel.Cells($x,38).Value

        $objContact.OtherAddressPostalCode = $objExcel.Cells($x,39).Value

        $objContact.OtherAddressState = $objExcel.Cells($x,40).Value

        $objContact.OtherAddressStreet = $objExcel.Cells($x,41).Value

        $objContact.BusinessTelephoneNumber = $objExcel.Cells($x,42).Value

        $objContact.Business2TelephoneNumber = $objExcel.Cells($x,43).Value

        $objContact.CarTelephoneNumber = $objExcel.Cells($x,44).Value

        $objContact.CompanyMainTelephoneNumber = $objExcel.Cells($x,45).Value

        $objContact.HomeTelephoneNumber = $objExcel.Cells($x,46).Value

        $objContact.MobileTelephoneNumber = $objExcel.Cells($x,47).Value

        $objContact.OtherTelephoneNumber = $objExcel.Cells($x,48).Value

        $objContact.Spouse = $objExcel.Cells($x,50).Value

        $objContact.Subject = $objExcel.Cells($x,51).Value

        $objContact.Title = $objExcel.Cells($x,52).Value

        $objContact.WebPage = $objExcel.Cells($x,53).Value

        ;---------------------------------------------------------------------------------------------

        $objContact.Save

        $x = $x + 1

    Until $objExcel.Cells($x,25).Value = ""

    $objExcel.Quit

HP Server locking up / freezing / not responding after Windows 2003 SP2 upgrade

2008-08-13T13:55:00.001-04:00

If anyone runs into any issues with an HP Proliant ML350 G5 or other Proliant server after installing Windows 2003 SP2, take a look at the following link for a resolution.

http://tinyurl.com/66vyga

This is caused by the Smart Array SAS/SATA controller driver version 6.6.0 or earlier.

Just download and install the latest driver available on the web site.